# Custom Serialization

If you really want to get extra funky and control how your components are serialized, you can fall back on our conventions. If the CFC has a public method called `$serialize()`, it will be called and its output (must be a *string*) will be saved in Couchbase. The CFC can also have a public method called `$deserialize( id, data )`, that if declared will be called and given the data so it can populate itself.

## CustomUser.cfc

```javascript
// CustomUser is an object that implements its own serialization scheme
// using pipe-delimited lists to store the data instead of JSON.  It has both
// a $serialize() and $deserialize() method to facilitate that.
component accessors="true"{

    property name="firstName";
    property name="lastName";
    property name="age";

    function $serialize(){
        // Serialize as pipe-delimited list
        return '#getFirstName()#|#getLastName()#|#getAge()#';
    }

    function $deserialize( ID, data ){
        // Deserialize the pipe-delimited list
        setFirstName( listGetAt( data, 1, '|' ) );
        setLastName( listGetAt( data, 2, '|' ) );
        setAge( listGetAt( data, 3, '|' ) );        
    }
}
```

## Usage

```javascript
user = new CustomUser();
user.setFirstName( "Brad" );
user.setLastName( "Wood" );
user.setAge( 45 );

couchbase.upsert( 'half-pipe', user );

reinflatedUser = couchbase.get( id="half-pipe", inflateTo='CustomUser' );

writeOutput( reinflatedUser.getFirstName() );
writeOutput( reinflatedUser.getLastName() );
writeOutput( reinflatedUser.getAge() );
```


---

# Agent Instructions: Querying This Documentation

If you need additional information that is not directly available in this page, you can query the documentation dynamically by asking a question.

Perform an HTTP GET request on the current page URL with the `ask` query parameter:

```
GET https://cfcouchbase.ortusbooks.com/usage/components/custom-serialization.md?ask=<question>
```

The question should be specific, self-contained, and written in natural language.
The response will contain a direct answer to the question and relevant excerpts and sources from the documentation.

Use this mechanism when the answer is not explicitly present in the current page, you need clarification or additional context, or you want to retrieve related documentation sections.